// Persistence Of Vision raytracer version 3.0 sample file.
// Compound image file cobbled together by Simon Smith

#version 3.0
global_settings { assumed_gamma 2.2 }

#include "shapes.inc"
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

camera {
   location <10, 70, 160>
   direction <0.0, 0.0, 1.67>
   up <0.0, 1.0, 0.0>
   right <4/3, 0.0, 0.0>
   look_at <70, 7, 15>
}

// Define a couple of colors for the light sources.
#declare MainLight = color red 0.8 green 0.8 blue 0.8
#declare FillLight = color red 0.23 green 0.23 blue 0.25
light_source { <150.0, 180.0, -300.0> color MainLight }
light_source { <50, 100, 50> color FillLight }


// source image is 649x488x256 according to my machine;
// will be mapped to a 1x1x1 box, so we scale it a little to
// get the correct aspect ratio

#declare Scaler = <649/649, 256/649, 488/649>

height_field  {
   gif "blue_fractal.gif" smooth scale Scaler
   water_level 0.0

  pigment { gradient y scale 0.06
      color_map {
         [0.00 0.7 color Red color Blue]
         [0.7 1.0 color Blue color Med_Purple]
      }
   }
   finish {
      ambient 0.2         // Very dark shadows
      diffuse 0.8         // Whiten the whites
      phong 0.75          // Fairly shiny
      phong_size 100.0    // with tight highlights
      specular 1.0
      roughness 0.005
   }

   scale <150, 750, 150>
}

// Sky sphere 
sphere { <0.0, 0.0, 0.0>, 1000.0
   pigment {
      gradient y     // Fade from yellow to orange to red to black 
      color_map {
         [0.00 0.10 color Yellow color Orange] // Yellow at horizon
         [0.10 0.15 color Orange color Red]    // Fade to orange to red
         [0.15 0.27 color Red   color Black ]  // then to dark red
         [0.27 1.01 color Black  color Black ] // to Black at zenith
      }
      quick_color SummerSky
      scale 1000                    // Big enough to surround the universe
   }
   finish {
      ambient 1.0                 // Keep objects from casting shadows 
      diffuse 0.0                 // All light comes from ambient sources 
   }
}

// Ocean
plane { y, 10
   texture {
      T_Chrome_2D
      normal {
         waves 0.05
         frequency 5000.0
         scale 3000.0
      }
   }
}

// Pool
plane { y, 10.1
   texture {
      T_Chrome_2D
      normal {
         ripples 0.1
         frequency 5000.0
         scale 8000.0
         rotate 3*y
      }
   }
clipped_by { box { <1,1,1>, 150*Scaler } } }

// end of file